原來也想繼續使用自定義函數來達成，因功力不夠而作罷（後來 [太陽之子] 有做了一個出來，已經收錄在範例檔Module2中，歡迎參考。另 [Dune in mud 小沙魚 in mu] 也發表了一個，也收錄在範例檔Module4中，真是一山比一山高），改以程序配合工作表的CHANGE事件, 來自動顯示計算公式。其中主要是利用 DirectPrecedents 屬性找出公式參照到本工作表的哪些儲存格，然後將這些儲存格的值替換掉公式的位址達成需求。

1. 一般模組 Module1
   Option Explicit
   '本程式碼假設在B欄輸入公式...數值計算公式
   '則在A欄顯示不帶"="開頭的公式字串
   '引數 Rng 為輸入公式的儲存格
   

   ---

   
   Sub ShFormula(Rng As Range)
       Dim thePrece     '前導範圍之位址
       Dim Addresses   '前導範圍位址之集合
       Dim theCell As Range    '單一前導儲存格
       Dim theFor As String    '公式字串
       With Rng            '對於輸入公式的儲存格
           '首先檢查有否發生循環參照, 避免程序陷入無窮堆疊
           If Not .Worksheet.CircularReference Is Nothing Then
               MsgBox "發生循環參照於" & .Worksheet.CircularReference.Address
               Exit Sub
           End If
           '若不是公式, 將前面A欄清空
           If Not .HasFormula Then
               .Previous = ""
               Exit Sub
           End If
           '取的公式字串並且刪除前面=號
           theFor = Replace(.Formula, "=", "", 1, 1)
           theFor = Replace(theFor, "$", "")
           '取得當前工作表的前導範圍, 未處理跨工作表或外部參照
           On Error Resume Next
           Addresses = Split(.DirectPrecedents.Address(0, 0), ",")
           '測試是否已經有取得任何前導範圍
           If Err.Number = 0 Then
               '遍歷各前導範圍
               For Each thePrece In Addresses
                   '遍歷個範圍中之儲存格
                   For Each theCell In Range(thePrece)
                       '將公式的位址換成該位址的值
                       theFor = Replace(theFor, theCell.Address(0, 0), .Worksheet.Range(theCell.Address(0, 0)), 1, 1)
                   Next
               Next
           End If
           .Previous = theFor  '將字串賦予左邊的儲存格
           Err.Clear
           Addresses = Null    '清空變數Addresses, 因為下面還要用
           '是否有從屬儲存格
           On Error Resume Next
           Addresses = Split(.DirectDependents.Address(0, 0), ",")
           '若有的話須將從屬儲存格的左邊公式顯示一併處理
           If Err.Number = 0 Then
               For Each thePrece In Addresses
                   For Each theCell In Range(thePrece)
                       '不需再寫程序, 遞迴呼叫即可
                       ShFormula theCell
                   Next
               Next
           End If
       End With
   End Sub
2. 工作表模組 Sheet1
   Option Explicit
   

   ---

   '利用工作表的CHANGE事件, 自動化
   Private Sub Worksheet_Change(ByVal Target As Range)
   With Target.Cells(1)
       If .Column = 2 Then
           ShFormula Target.Cells(1)
       End If
   End With
   End Sub

下載範例檔案

下載範例檔案