//一直欄多少張相片
_global.COUNT_PHOTOS_COL = 4;
//縮圖間距
_global.T_PHOTO_OFFSET = 5;
//縮圖大小
_global.T_PHOTO_SIZE = 70;
//相片資料
var PHOTO_DIR:String = "http://pic.bahamut.com.tw/NEWODIN/9/";
var photoFiles:Array = new Array();
photoFiles.push("0052192");
photoFiles.push("0052193");
photoFiles.push("0052194");
photoFiles.push("0052195");
photoFiles.push("0052196");
photoFiles.push("0052197");
photoFiles.push("0052198");
photoFiles.push("0052199");
photoFiles.push("00521910");
photoFiles.push("00521911");
photoFiles.push("00521912");
photoFiles.push("00521913");
photoFiles.push("00521914");
photoFiles.push("00521915");
photoFiles.push("00521916");
photoFiles.push("00521917");
//負責載入的mc
var photos_mc:MovieClip = this.createEmptyMovieClip("photos_mc", 2);
for (var i = 0; i< photoFiles.length; i++) {
	//每一個放圖片的容器
	var photo_mc:MovieClip = photos_mc.createEmptyMovieClip("photo"+i+"_mc"
						, photos_mc.getNextHighestDepth());
	//允許這個容器，能發出自定事件
	mx.events.EventDispatcher.initialize(photo_mc);
	//將一些參數定義給這個容器
	photo_mc.id = i;
	photo_mc.file = PHOTO_DIR+photoFiles[i];
	photo_mc.loadImg_mc = photo_mc.createEmptyMovieClip("loadImg_mc", 2);
	//當別的相片容器 photoLoaded 時，這個 mc 要能接收並處理
	photo_mc.photoLoaded = function(evtObj:Object) {
		//當執行權已經到自己身上時，就不用再監聽上一個 mc 的事件了
		if (this.id >0) {
			photos_mc["photo"+(i-1)+"_mc"].removeEventListener(this);
		}
		//此容器開始載入相片
		this.loadClip(this.file, this.loadImg_mc);
	};
	photo_mc.loadClip = function(file:String, target_mc:MovieClip) {
		//位置
		this._x = Math.floor(this.id/_global.COUNT_PHOTOS_COL)
				*(_global.T_PHOTO_SIZE+_global.T_PHOTO_OFFSET);
		this._y = Math.floor(this.id%_global.COUNT_PHOTOS_COL)
				*(_global.T_PHOTO_SIZE+_global.T_PHOTO_OFFSET);
		//載入
		target_mc.loadMovie(file);
		//訊息
		this.createTextField("progress_txt"
					, this.getNextHighestDepth()
					, 0, 0, 10, 5);
		this.progress_txt.autoSize = true;
		this.progress_txt.text = "0%";
		//不斷檢查
		this.onEnterFrame = function() {
			//載入進度
			var loadedBytes:Number = this.loadImg_mc.getBytesLoaded();
			var totalBytes:Number = this.loadImg_mc.getBytesTotal();
			var p = Math.round((loadedBytes/totalBytes)*100);
			this.progress_txt.text = p+"%";
			if (totalBytes >0 && loadedBytes == totalBytes) {
				//移除訊息
				this.progress_txt.removeTextField();
				//大小
				var p = _global.T_PHOTO_SIZE
					/(this._width >this._height
					? this._width : this._height);
				this._width *= p;
				this._height *= p;
				//點選效果
				this.onRelease = function() {
					getURL(this.file, "_blank");
				};
				//當這個容器載入相片完成，送出一個 photoLoaded 事件
				this.dispatchEvent({target:this, type:"photoLoaded"});
				//移除onEnterFrame
				this.onEnterFrame = null;
			}
		};
	};
	if (i >0) {
		//上一個 mc 以這一個 mc 當作事件監聽者
		photos_mc["photo"+(i-1)+"_mc"].addEventListener("photoLoaded", photo_mc);
	}
}
//開始載入
photos_mc.photo0_mc.loadClip(photos_mc.photo0_mc.file, photos_mc.photo0_mc.loadImg_mc);